Classes have members, and it is entirely possible for the members of a class to be another user-defined type. Thus, a Button class might have a member of type Location, and a Location class might contain members of type Point. Finally, Point might contain members of type Integer.
At times, the contained class might exist only to serve the outer class, and there might be no reason for it to be otherwise visible. (In short, the contained class acts as a helper class.) You can define the helper class within the definition of the outer class. The contained, inner class is called a nested class, and the class that contains it is called, simply, the outer class.
Nested classes have the advantage of access to all the members of the outer class. That is, a method of a nested class can access private members of the outer class.
In addition, the nested class can be hidden from all other classes�that is, it can be private to the outer class.
Finally, a nested class that is public is accessed within the scope of the outer class. If Button is the outer class, and Location is the (public) inner class, you refer to Location as Button.Location, with the outer class (Button) acting (more or less) as a namespace or scope.
Example 6-6 features a nested class of Fraction named FractionArtist. The job of FractionArtist is to render the fraction on the console. In this example, the rendering is handled by a pair of simple WriteLine( ) statements.
Option Strict On
Imports System
Public Class Fraction
Private numerator As Integer
Private denominator As Integer
Public Sub New( _
ByVal numerator As Integer, ByVal denominator As Integer)
Me.numerator = numerator
Me.denominator = denominator
End Sub 'New
Public Overrides Function ToString( ) As String
Return [String].Format("{0}/{1}", numerator, denominator)
End Function 'ToString
' Nested Class
Class FractionArtist
Public Sub Draw(ByVal f As Fraction)
Console.WriteLine("Drawing the numerator: {0}", f.numerator)
Console.WriteLine( _
"Drawing the denominator: {0}", f.denominator)
End Sub 'Draw
End Class 'FractionArtist
End Class 'Fraction
Public Class Tester
Shared Sub Main( )
Dim f1 As New Fraction(3, 4)
Console.WriteLine("f1: {0}", f1.ToString( ))
Dim fa As New Fraction.FractionArtist( )
fa.Draw(f1)
End Sub 'Main
End Class 'Tester
The nested class is shown in bold. The FractionArtist class provides only a single member, the Draw( ) method. What is particularly interesting is that Draw( ) has access to the private data members f.numerator and f.denominator, to which it would not have had access if it were not a nested class.
Notice in Main( ) that to declare an instance of this nested class, you must specify the type name of the outer class:
Dim fa As New Fraction.FractionArtist( )
FractionArtist is scoped to within the Fraction class.
 |
|
|
| Top |