Recipe 18.9. Program: expn and vrfy

18.9. Program: expn and vrfy

This program talks directly to an SMTP server and uses the EXPN and VRFY commands to figure out whether an address is going to work. It isn't perfect, because it relies on the remote SMTP giving meaningful information with the EXPN and VRFY commands. It uses Net::DNS if available, but can also work without.

This program inspects $0 (the program name) to see how it was called. If run as expn, it uses the EXPN command; if called as vrfy, it uses the VRFY command. Use links to install it with two names:

% cat > expn
#!/usr/bin/perl -w
...
^D
% ln expn vrfy

When you run it with an email address, the program reports what the mail server says when you try to EXPN or VRFY the address. If you have Net::DNS installed, it tries all hosts listed as mail exchangers in the DNS entry for the address.

Here's what it looks like without Net::DNS:

% expn [email protected]
Expanding gnat at frii.com ([email protected]):
calisto.frii.com Hello coprolith.frii.com [207.46.130.14],
    pleased to meet you
<[email protected]>

And here's the same address with Net::DNS installed:

% expn [email protected]
Expanding gnat at mail.frii.net ([email protected]):
deimos.frii.com Hello coprolith.frii.com [207.46.130.14],
    pleased to meet you
Nathan Torkington <[email protected]>

Expanding gnat at mx1.frii.net ([email protected]):
phobos.frii.com Hello coprolith.frii.com [207.46.130.14],
    pleased to meet you
<[email protected]>

Expanding gnat at mx2.frii.net ([email protected]):
europa.frii.com Hello coprolith.frii.com [207.46.130.14],
    pleased to meet you
<[email protected]>

Expanding gnat at mx3.frii.net ([email protected]):
ns2.winterlan.com Hello coprolith.frii.com [207.46.130.14],
    pleased to meet you
550 gnat... User unknown

The program is shown in Example 18.3.

Example 18.3: expn

#!/usr/bin/perl -w
# expn -- convince smtp to divulge an alias expansion
use strict;
use IO::Socket;
use Sys::Hostname;

my $fetch_mx = 0;
# try loading the module, but don't blow up if missing
eval {    
    require Net::DNS;
    Net::DNS->import('mx');
    $fetch_mx = 1;
};

my $selfname = hostname();
die "usage: $0 address\@host ...\n" unless @ARGV;

# Find out whether called as "vrfy" or "expn".
my $VERB = ($0 =~ /ve?ri?fy$/i)  ? 'VRFY' : 'EXPN';
my $multi = @ARGV > 1;
my $remote;

# Iterate over addresses give on command line.
foreach my $combo (@ARGV) {
    my ($name, $host) = split(/\@/, $combo);
    my @hosts;
    $host ||= 'localhost';
    @hosts = map { $_->exchange } mx($host)     if $fetch_mx;
    @hosts = ($host)   unless @hosts;

    foreach my $host (@hosts) { 
        print $VERB eq 'VRFY' ? "Verify" : "Expand", 
            "ing $name at $host ($combo):";

        $remote = IO::Socket::INET->new(
               Proto    => "tcp",
               PeerAddr => $host,
               PeerPort => "smtp(25)",
           ); 

        unless ($remote) { 
            warn "cannot connect to $host\n";
            next;
        }
        print "\n";

        $remote->autoflush(1);

        # use CRLF network line terminators
        print $remote "HELO $selfname\015\012";
        print $remote "$VERB $name\015\012";
        print $remote "quit\015\012";
        while (<$remote>) {
            /^220\b/ && next;
            /^221\b/ && last;
            s/250\b[\-\s]+//;
            print;
        } 
        close($remote) or die "can't close socket: $!";
        print "\n"; #  if @ARGV;
    }
}


18.8. Using Whois to Retrieve Information from the InterNIC		19. CGI Programming