Special Array Indices (Learning Perl, 3rd Edition)

3.2. Special Array Indices

If you store into an array element that is beyond the end of the array, the array is automatically extended as needed -- there's no limit on its length, as long as there's available memory for Perl to use. If intervening elements need to be created, they'll be created as undef values.

$rocks[0] = 'bedrock';      # One element...
$rocks[1] = 'slate';        # another...
$rocks[2] = 'lava';         # and another...
$rocks[3] = 'crushed rock'; # and another...
$rocks[99] = 'schist';      # now there are 95 undef elements

Sometimes, you need to find out the last element index in an array. For the array of rocks that we've just been using, the last element index is $#rocks.[70] That's not the same as the number of elements, though, because there's an element number zero. As seen in the code snippet below, it's actually possible to assign to this value to change the size of the array, although this is rare in practice.[71]

[70]Blame this ugly syntax on the C shell. Fortunately, we don't have to look at this very often in the real world.

[71]This is very infrequently done to "pre-size" an array, so that Perl won't need to allocate memory in many small chunks as an array grows. See the Perl documentation for more information, in the unlikely case that you need this.

$end = $#rocks;                  # 99, which is the last element's index
$number_of_rocks = $end + 1;     # okay, but we'll see a better way later
$#rocks = 2;                     # Forget all rocks after 'lava'
$#rocks = 99;                    # add 97 undef elements (the forgotten rocks are
                                 # gone forever)
$rocks[ $#rocks ] = 'hard rock'; # the last rock

Using the $#name value as an index, like that last example, happens often enough that Larry has provided a shortcut: negative array indices count from the end of the array. But don't get the idea that these indices "wrap around." If you've got three elements in the array, the valid negative indices are -1 (the last element), -2 (the middle element), and -3 (the first element). In the real world, nobody seems to use any of these except -1, though.

$rocks[ -1 ] = 'hard rock'; # easier way to do that last example above
$dead_rock = $rocks[-100];  # gets 'bedrock'
$rocks[ -200 ] = 'crystal'; # fatal error!


3. Lists and Arrays		3.3. List Literals